Skip to content

Instantly share code, notes, and snippets.

@cppio
Last active May 28, 2026 23:21
Show Gist options
  • Select an option

  • Save cppio/71e3b04949b82f0d795326ca848e4c11 to your computer and use it in GitHub Desktop.

Select an option

Save cppio/71e3b04949b82f0d795326ca848e4c11 to your computer and use it in GitHub Desktop.
{-# OPTIONS --safe --cubical #-}
open import Agda.Builtin.Cubical.Path
module Homotopy {ℓ} {A : Set ℓ} {x y : A} (p q : x ≡ y) where
open import Agda.Primitive.Cubical renaming ( primIMin to _∧_
; primIMax to _∨_
; primINeg to ~_
; primHComp to hcomp
)
refl : {a : A} → a ≡ a
refl {a} _ = a
H₀ = p ≡ q
H₁ = PathP (λ i → p i ≡ y) q refl
H₂ = PathP (λ i → x ≡ p i) refl q
{-
p i
x-------y
|\ /|
| x---y |
q j| | | |y
| y---y |
|/ \|
y-------y
y
-}
H₀→H₁ : H₀ → H₁
H₀→H₁ h i j = hcomp (λ { k (i = i0) → h k j
; k (i = i1) → y
; k (j = i0) → p i
; k (j = i1) → y
}) (p (i ∨ j))
{-
x
x-------x
|\ /|
| y---y |
p j| | | |q j
| y---y |
|/ \|
y-------y
y
-}
H₁→H₀ : H₁ → H₀
H₁→H₀ h i j = hcomp (λ { k (i = i0) → h j (~ k)
; k (i = i1) → q (j ∨ ~ k)
; k (j = i0) → q (~ k)
; k (j = i1) → y
}) y
{-
x
x-------x
|\ /|
| x---y |
x| | | |q j
| y---y |
|/ \|
x-------y
p i
-}
H₁→H₂ : H₁ → H₂
H₁→H₂ h i j = hcomp (λ { k (i = i0) → p (j ∧ ~ k)
; k (i = i1) → q (j ∨ ~ k)
; k (j = i0) → q (i ∧ ~ k)
; k (j = i1) → p (i ∨ ~ k)
}) (h j i)
{-
p i
x-------y
|\ /|
| x---x |
q j| | | |y
| x---y |
|/ \|
y-------y
y
-}
H₂→H₁ : H₂ → H₁
H₂→H₁ h i j = hcomp (λ { k (i = i0) → q (j ∧ k)
; k (i = i1) → p (j ∨ k)
; k (j = i0) → p (i ∧ k)
; k (j = i1) → q (i ∨ k)
}) (h j i)
{-
x
x-------x
|\ /|
| x---x |
x| | | |q j
| x---y |
|/ \|
x-------y
p i
-}
H₀→H₂ : H₀ → H₂
H₀→H₂ h i j = hcomp (λ { k (i = i0) → x
; k (i = i1) → h k j
; k (j = i0) → x
; k (j = i1) → p i
}) (p (i ∧ j))
{-
x
x-------x
|\ /|
| x---x |
p j| | | |q j
| x---x |
|/ \|
y-------y
y
-}
H₂→H₀ : H₂ → H₀
H₂→H₀ h i j = hcomp (λ { k (i = i0) → h j k
; k (i = i1) → q (j ∧ k)
; k (j = i0) → x
; k (j = i1) → q k
}) x
Sign up for free to join this conversation on GitHub. Already have an account? Sign in to comment