Skip to content

Instantly share code, notes, and snippets.

@cppio
Created June 10, 2026 02:41
Show Gist options
  • Select an option

  • Save cppio/4cbbfff5fda97250fe4806885f969015 to your computer and use it in GitHub Desktop.

Select an option

Save cppio/4cbbfff5fda97250fe4806885f969015 to your computer and use it in GitHub Desktop.
Expressing the side conditions for the cubical primitives using cubical subtypes.
{-# OPTIONS --safe --cubical #-}
module _ where
open import Agda.Primitive.Cubical renaming ( primIMin to _∧_
; primIMax to _∨_
; primINeg to ~_
)
open import Agda.Builtin.Cubical.Sub renaming (primSubOut to outS)
abstract
transp : ∀ φ {ℓ} (A₀ : Partial φ _) (A : Sub (I → Set ℓ) φ λ .p _ → A₀ p) (u : outS A i0) → Sub (outS A i1) φ λ { (φ = i1) → u }
transp φ A₀ A u = inS (primTransp (outS A) φ u)
hcomp : ∀ {ℓ A φ} (u : I → _) → Sub {ℓ} A φ (u i0) → Sub A φ (u i1)
hcomp u u₀ = inS (primHComp u (outS u₀))
transport : ∀ {ℓ} (A : I → Set ℓ) → A i0 → A i1
transport A u = outS (transp i0 isOneEmpty (inS A) u)
transportFill : ∀ {ℓ A} u → PathP {ℓ} A u (transport A u)
transportFill {A = A} u i = outS (transp (~ i) (λ _ → A i0) (inS λ j → A (i ∧ j)) u)
hfill : ∀ {ℓ A φ} u u₀ i → Sub A _ λ { (φ = i1) → u i itIsOne ; (i = i0) → outS u₀ ; (i = i1) → outS (hcomp {ℓ} {A} {φ} u u₀) }
hfill {φ = φ} u u₀ i = inS (outS (hcomp (λ { j (φ = i1) → u (i ∧ j) itIsOne
; j (i = i0) → outS u₀
}) (inS (outS u₀))))
Sign up for free to join this conversation on GitHub. Already have an account? Sign in to comment